Excel VBAのオブジェクト型変数の生成から破棄まで　１．勘違い編

以前にこのようなツイをしたところ、諸先輩方から色々なアドバイスを頂きました。

某書の写経です。
このコードでCollectionに追加した「Studentクラス」の中身が更新されて、「Studentクラス」を破棄した時にCollectionに追加した「Studentクラス」は影響を受けないことが両立するのでしょうか？
mItems.Add vStudentがEnd with下なら自分的には納得できるのですが。#助けてVBA pic.twitter.com/hHirs98fKO
— Kou Excelが大好きだ！ (@LoverExcel) 2021年9月23日

下記ツイのツリーにも記載しましたが、改めて自分がモヤモヤと勘違いしていた点と、教えて頂いてこうだろうと思って点をまとめてみたいと思います。

先日は下記悩みに色々とアドバイスを頂きましてありがとうございます。
複数の方から図解してみると良いとアドバイスを頂きましたので、当初勘違いしてモヤモヤしていたこと、アドバイスを元に修正したイメージを拙いながらまとめてみようと思います。 https://t.co/B86PdFcPJx
— Kou Excelが大好きだ！ (@LoverExcel) 2021年9月26日

オブジェクト変数での疑問点
[勘違い版]検証用コード
[勘違い版]オブジェクト型変数の生成
[勘違い版]オブジェクト変数を渡す
- 値渡し的イメージ
- 参照渡し的イメージ
まとめ

ひょっとすると私と同じ様な勘違いをしている人もいるかも知れません。
今回は当初私の頭の中にあった図を紹介いたします。
当初の私の勘違いですので明らかに間違っていますのでご注意ください

オブジェクト変数での疑問点

下記は「Excel VBA 実践のための技術」からの抜粋です。

Public Sub Add(ByVal vID As String, _
               ByVal vName As String, _
               ByVal vAge As Long, _
               ByVal vMobile As String)
     
     Dim vStudent As Student  'Studentはユーザー定義クラス
     
     mItemDictionary.Add Key:=vID, item:=mItems.Count + 1
     Set vStudent = New Student
'↓↓↓↓↓ここから
     mItems.Add vStudent      'Collection.addです
     
     With vStudent
          .ID = vID
          .Name = vName
          .Age = vAge
          .Mobile = vMobile
     End With
     Set vStudent = Nothing

'↑↑↑↑↑ここまで
End Sub

疑問点は上記コード内の「ここから」～「ここまで」のコードです。

Collectionに追加したStudentクラスの中身が更新されて(with句内の処理)、
Studentクラスを破棄した時(set vStudent = nothing)に、
Collection内のStudentクラスが影響を受けない事がわからない。

[勘違い版]検証用コード

ここから上記コードをどのように勘違いしていたからわからなかったのか記載いたします。

検証用にもう少し簡略化して全体を見れるコードを用意しました。

Studentクラス

'### Studentクラス
Private mName As String

Public Property Let Name(ByVal vName As String)
     mName = vName
End Property

Public Property Get Name() As String
     Name = mName
End Property

標準モジュール

Sub オブジェクト参照テスト()
     Dim 名簿Col As Collection
     Set 名簿Col = New Collection
     Dim 生徒A As Student
     Set 生徒A = New Student
     
     名簿Col.Add 生徒A
     生徒A.Name = "Kou"
     Debug.Print 名簿Col(1).Name
     
     Set 生徒A = Nothing
     Debug.Print 名簿Col(1).Name
End Sub