配列から空白(Empty)を取り除く方法

セル範囲を一括で配列に取り込んだ際などに、空白が紛れ込むことがあります。

そのような場合に配列から空白を除く方法を検証してみます。

空白のある元データ

簡単なデータを用意しました。
f:id:ExcelLover:20181223130243j:plain

このセル範囲を配列に取込、空白の削除を行うのが以下のコードです。

Sub EmptyDelete()
     Dim myVar As Variant
     
     myVar = Range("A2:A6").Value
     myVar = ArrayEmptyDelete(myVar)
     Range("C2").Resize(UBound(myVar) + 1, 1).Value = _
          WorksheetFunction.Transpose(myVar)
End Sub

セル範囲を取り込んだ際の配列の状況が以下のようになっています。 f:id:ExcelLover:20181223130306j:plain

３つ目の項目が取り込む値が無いため、Variant型の初期値であるEmptyになっています。

変数の初期値についてはこちら

www.excellovers.com

今回はこのEmptyを削除して配列の要素数を減らしたいと思います。

空白を削除する関数

上記のコードで記載されていた

ArrayEmptyDelete関数が配列からEmptyを削除して要素数を減らす関数です。

コードは以下の通り

'###差し当たって１列の２次元配列を想定
'###取り込んだ２次元配列から空白を削除して１次元配列として返す
Function ArrayEmptyDelete(myArray As Variant) As Variant
    '①
     If Not IsArray(myArray) Then ArrayEmptyDelete = Array(): Exit Function
     
     Dim i As Long
     Dim myVar As Variant
     Dim RowData As Variant
     
     ReDim myVar(UBound(myArray))
     
     For Each RowData In myArray
          '②
          If Not IsEmpty(RowData) Then
               myVar(i) = RowData
               i = i + 1
          End If
     Next
     ReDim Preserve myVar(i - 1)
     ArrayEmptyDelete = myVar
End Function